// Tavern, First Floor Drunkard 
ON INIT {
 INVENTORY ADDMULTI "JEWELRY\\GOLD_COIN\\GOLD_COIN" 8
 INVENTORY ADD "PROVISIONS\\BOTTLE_WINE\\BOTTLE_WINE"
 SET £friend "TAVERN"
 SET §reflection_mode 1
 ACCEPT
}

ON INITEND {
 SET £misc [customer_tavern_reflection_male]
 TWEAK HEAD "human_villager_head6"
 TWEAK LEGS "human_villager_legs2"
 TWEAK TORSO "human_villager_chest2"
 TWEAK SKIN "npc_human_villager_leg2a_chest2_a" "npc_human_clothes_d"
 ATTACH MUG_FULL_0002 "BEER_ATTACH" SELF "left_attach"
 SET £attached_object "MUG_FULL_0002"
 LOADANIM ACTION3 "human_guard_wounded_cycle"
 LOADANIM ACTION2 "human_normal_drink_cycle2"
 PLAYANIM -l ACTION2
 SET §frozen 1
 SETWEAPON SHORT_SWORD_STEEL
 SENDEVENT -ir DURABILITY 100 "63"
 SET_NPC_STAT damages 12
 PHYSICAL OFF
 ACCEPT
}

ON CALL_HELP {
 DETACH MUG_FULL_0002 SELF
 ACCEPT
}

ON REACHEDTARGET {
  IF (^TARGET == MARKER_0423) {
    SET_NPC_STAT life 1
    FORCE_ANGLE 0
    PLAYANIM -l ACTION3
    SET §frozen 1
    ACCEPT
  }
 ACCEPT
}

ON CHAT {
 IF (^SPEAKING == 1) ACCEPT
 SPEAK [customer_tavern_misc_male] NOP
 ACCEPT
}

ON CUSTOM {
  IF (#SHUT_UP == 1) {
    SENDEVENT CUSTOM HUMAN_BASE_0097 "TALK01"
    ACCEPT
  }
  IF (^$PARAM1 == "GO") {
    PLAYANIM -e ACTION2 PLAYANIM NONE
    DETACH MUG_FULL_0002 SELF
    SET £attached_object "NONE"
    DESTROY MUG_FULL_0002
    LOADANIM WALK "human_kultar_walk_wounded"
    PHYSICAL ON
    BEHAVIOR MOVE_TO
    SETTARGET MARKER_0423
    SET §reflection_mode 1
    ACCEPT
  }
  IF (^$PARAM1 == "TALK") {
    SET §reflection_mode 0
    SPEAK [customer_misc_tizzy] SENDEVENT CUSTOM HUMAN_BASE_0097 "TALK"
    ACCEPT
  }
  IF (^$PARAM1 == "TALK01") {
    SPEAK [customer_misc_tizzy] SENDEVENT CUSTOM HUMAN_BASE_0097 "TALK01"
    ACCEPT
  }
 IF (^$PARAM1 == "TALK02") SET §reflection_mode 1
 ACCEPT
}