ON INIT {
 SETNAME [description_plant]
 SET_MATERIAL CLOTH
 SET_GROUP PROVISIONS
 SET_PRICE 80
 PLAYERSTACKSIZE 10
 SET_STEAL 50
 SET §scale 80
 SET #TMP ~^RND_40~
 INC §scale #TMP 
 SETSCALE §scale
 SET_WEIGHT 0
 SETEQUIP identify_value 31
 SET §identified 0
 TWEAK ICON "Plant_Unknown[icon]"
 ACCEPT
}

ON IDENTIFY {
 SETNAME [description_morning_glory]
 TWEAK ICON "Morning_Glory[icon]"
 SET §identified 1
 ACCEPT
}

ON COMBINE {
 IF (^$param1 ISCLASS "CRUSHER") {
    IF (§identified == 0) {
      SPEAK -p [player_no] NOP
      ACCEPT
    }
PLAY "CRUSHING"
 REPLACEME \\magic\\Powder_morning_glory\\Powder_morning_glory
 ACCEPT
 }
ACCEPT
}

ON FEINTE {
 SET §scale 5
 SETSCALE §scale
 OBJECT_HIDE SELF YES
 ACCEPT
}

ON CUSTOM { 
 IF (^$PARAM1 == "APPEAR") {
  IF (§done == 1) ACCEPT
  SET §done 1
  SENDEVENT CUSTOM MORNING_GLORY_0001 "APPEAR"
  SENDEVENT CUSTOM MORNING_GLORY_0002 "APPEAR"
  SENDEVENT CUSTOM MORNING_GLORY_0003 "APPEAR"
  SENDEVENT CUSTOM MORNING_GLORY_0004 "APPEAR"
  SENDEVENT CUSTOM MORNING_GLORY_0008 "APPEAR"
  SENDEVENT CUSTOM MORNING_GLORY_0008 "APPEAR"
  OBJECT_HIDE SELF OFF
  HALO -os 80
  TIMERhalo 1 7 HALO -f
  //PLAY "SFX_PLAYER_APPEARS"
  PLAYANIM ACTION1
  TIMERscale -m 19 50 GOTO SCALE 
  ACCEPT
 }
 ACCEPT
}
 
>>SCALE
SETSCALE §scale
INC §scale 5
ACCEPT