ON INIT {
SET §gone 0
 SET §chatpos 0
 ACCEPT
}
ON INITEND {
 SET §reflection_mode 0
 BEHAVIOR FRIENDLY
 SETTARGET TROLL_BASE_0003
 ACCEPT
}
ON RELOAD {
 IF (§gone == 1) {
  SET §gone 0
  OBJECT_HIDE SELF NO
  SET §reflection_mode 1
  BEHAVIOR Wander_around 200
  SETTARGET NONE
  ACCEPT
 }
 ACCEPT
}
ON CHAT {
  IF (#troll_enemy == 1) ACCEPT
  IF (^SPEAKING == 1) ACCEPT
  IF (§chatpos == 0) {
    IF (#TROLLHERO == 1) {
      GOSUB START_CHAT
      SPEAK [troll_greetings_friend] GOSUB END_CHAT
      ACCEPT
    }
    GOSUB START_CHAT
    SPEAK [troll_greetings] GOSUB END_CHAT
    ACCEPT
  }
 ACCEPT
 }
ON CUSTOM {
  IF (^$PARAM1 == "HERE_HE_COMES" ) {
    IF (^SPEAKING == 1) {
     SENDEVENT CUSTOM TROLL_BASE_0003 "LETS_TALK2"
     ACCEPT
    }
    IF (#SHUT_UP != 1) SPEAK [Troll_chat2] SENDEVENT CUSTOM TROLL_BASE_0003 "LETS_TALK2"
    ACCEPT
  }
  IF (^$PARAM1 == "LETS_TALK3" ) {
    IF (^SPEAKING == 1) GOTO NOW
    IF (#SHUT_UP != 1) SPEAK [Troll_chat4] GOTO NOW
    ACCEPT
  }
  IF (^$PARAM1 == "HELP_HUMANS") {
   SET §reflection_mode 0
   SET §gone 1
   OBJECT_HIDE -m SELF YES
   ACCEPT
  }
 ACCEPT
 }

ON DIE {
 INVENTORY ADD "Quest_item\amulet_troll\\AMULET_TROLL"
 ACCEPT
}

>>NOW
SET §reflection_mode 1
BEHAVIOR Wander_around 400
SETTARGET NONE
ACCEPT

//#behavior

// ---------------------------------------------------------------------------------
// BEHAVIOR INCLUDE START ----------------------------------------------------------
// ---------------------------------------------------------------------------------
>>CLEAR_MICE_TARGET
 // if we care about mice : clear current mice target and listen to other mice
 IF ( §care_about_mice == 1 )
 {
  SET £targeted_mice "NOMOUSE"
  SETGROUP MICECARE // listen to other mice
 }
RETURN

>>SAVE_BEHAVIOR
 TIMERcolplayer OFF 
// to avoid TIMERcolplayer to restore the behavior 1 sec later
 IF (§main_behavior_stacked == 0) 
 {
  IF (§frozen == 1)
  { 
// frozen anim -> wake up !
    SET §frozen 0
    PLAYANIM NONE
    PLAYANIM -2 NONE
    PHYSICAL ON
    COLLISION ON
    BEHAVIOR FRIENDLY
    SETTARGET PLAYER
  }
  SET §main_behavior_stacked 1
  HEROSAY -d "STACK"
  BEHAVIOR STACK
 }
 ELSE
 { // behavior already saved : clear mice target if one
  GOSUB CLEAR_MICE_TARGET
 }
RETURN

>>RESTORE_BEHAVIOR
 IF (§main_behavior_stacked == 1) 
 {
  GOSUB CLEAR_MICE_TARGET
  HEROSAY -d "UNSTACK"
  BEHAVIOR UNSTACK
  SET §main_behavior_stacked 0
  RETURN
 }
IF (£init_marker != "NONE")
  { 
   BEHAVIOR MOVE_TO
   SETTARGET -a ~£init_marker~
   SETMOVEMODE WALK
   RETURN
  }
HEROSAY -d "go_home"
BEHAVIOR GO_HOME
SETTARGET PLAYER
RETURN

// ---------------------------------------------------------------------------------
// BEHAVIOR INCLUDE END ------------------------------------------------------------
// ---------------------------------------------------------------------------------

//#
//#LocalChat
// ---------------------------------------------------------------------------------
// LocalChat INCLUDE START ---------------------------------------------------------
// ---------------------------------------------------------------------------------
>>START_CHAT
 // save misc reflection mode
 SET §saved_reflection §reflection_mode
 // no more stupid reflections !
 SET §reflection_mode 0
 // fo not change behavior if frozen
 IF ( §frozen == 1 ) RETURN
 // save behavior (if not saved)
 GOSUB SAVE_BEHAVIOR
 // look at player
 BEHAVIOR FRIENDLY
 SETTARGET PLAYER
RETURN

>>END_CHAT
 SET_EVENT COLLIDE_NPC ON
 SET §collided_player 0
 // restor behavior only if not in fighting mode
 IF ( §fighting_mode == 0 )
 {
  // restore misc reflection mode
  SET §reflection_mode §saved_reflection
  // if frozen : don't restore behavior
  IF ( §frozen == 1 ) RETURN
  // restore behavior
  GOSUB RESTORE_BEHAVIOR
 }
RETURN
// ---------------------------------------------------------------------------------
// LocalChat INCLUDE END -----------------------------------------------------------
// ---------------------------------------------------------------------------------

//#