ON INIT {
 INVENTORY ADDMULTI "JEWELRY\\GOLD_COIN\\GOLD_COIN" 5
 SET £friend "TAVERN"
 SET §reflection_mode 0
 SET §drinking 0			// Used to know if npc is drinking and player cannot talk to him.
 SET £type "human_female_base"
 ACCEPT
}

ON INITEND {
 TWEAK ALL "human_female_villager"
 TWEAK SKIN "npc_human_villager_female_anon1" "npc_human_villager_female_anon3"
 LOADANIM ACTION2 "human_normal_sit_cycle"
 LOADANIM ACTION3 "human_normal_drink_cycle2"
 SET £misc [customer_tavern_reflection_female]
 PHYSICAL OFF
 OBJECT_HIDE -m SELF ON
 ACCEPT
}

ON LOAD {
 USEMESH "human_female_base\human_female_base.teo"
 ACCEPT
}

ON RELOAD {
  IF (#TROLL_QUEST > 1) {
    OBJECT_HIDE SELF OFF
    OBJECT_HIDE MUG_FULL_0008 OFF
    ATTACH MUG_FULL_0008 "BEER_ATTACH" SELF "left_attach"
    SET £attached_object "MUG_FULL_0008"
    PLAYANIM -l ACTION2
    SET §frozen 1
    TIMERdrink -i 0 25 GOTO DRINK
    ACCEPT
  }
 ACCEPT
}

ON CHAT {
 IF (^SPEAKING == 1) ACCEPT
 IF (§enemy == 1) ACCEPT
 IF (§drinking == 1) ACCEPT
 SPEAK [customer_tavern_misc_female] NOP
 ACCEPT
}

>>DRINK
  IF (^SPEAKING == 1) ACCEPT
  RANDOM 50 {
    SET §drinking 1
    PLAYANIM -2e ACTION3 GOTO DRINK2
    ACCEPT
  }
  ELSE {
    IF (^SPEAKING == 1) ACCEPT
    IF (#SHUT_UP == 1) ACCEPT
    SPEAK [customer_tavern_reflection_female] NOP
    ACCEPT
  }
 ACCEPT

>>DRINK2
 SET §drinking 0
 PLAYANIM -2e NONE PLAYANIM -l ACTION2
 ACCEPT