ON INITEND {
SET §friend 0
TWEAK SKIN "npc_trollbase_body" "npc_trollgrey_body"
TWEAK SKIN "npc_trollbase_head" "npc_trollgrey_head"
BEHAVIOR WANDER_AROUND 300
SET_SPEAK_PITCH 0.85
SETTARGET NONE
ACCEPT
}
ON RELOAD {
 IF (§enemy == 0) TELEPORT -i
 ACCEPT
}
ON DETECTPLAYER {
 IF (§friend == 1) ACCEPT
 IF (§enemy == 1) ACCEPT
 IF (^POSSESS_amulet_troll_0001 == 0) {
  SENDEVENT ATTACK_PLAYER SELF ""
  ACCEPT
 }
 SET §friend 1
 SENDEVENT -gr ~£friend~ FRIEND 9000 ""
 ACCEPT
}

ON FRIEND {
 SET §friend 1
 ACCEPT
}

ON CHAT {
  IF (^speaking == 1) ACCEPT
  IF (§friend == 1) {
    GOSUB START_CHAT
    SPEAK [Troll_greetings_friend] GOSUB END_CHAT
    ACCEPT
  }
  IF (^POSSESS_amulet_troll_0001 == 0) {
   IF (^speaking == 0) SPEAK [Troll_grunt] nop
   SENDEVENT ATTACK_PLAYER SELF ""
   ACCEPT
  }
  SET §friend 1
  IF (^speaking == 0) {
   GOSUB START_CHAT
   SPEAK [Troll_greetings_friend] GOSUB END_CHAT
  }
  SENDEVENT -gr ~£friend~ FRIEND 9000 ""
  ACCEPT
 }
 ACCEPT
}

ON DIE {
 INVENTORY ADD "Quest_item\amulet_troll\\AMULET_TROLL"
 ACCEPT
}

//#behavior

// ---------------------------------------------------------------------------------
// BEHAVIOR INCLUDE START ----------------------------------------------------------
// ---------------------------------------------------------------------------------
>>CLEAR_MICE_TARGET
 // if we care about mice : clear current mice target and listen to other mice
 IF ( §care_about_mice == 1 )
 {
  SET £targeted_mice "NOMOUSE"
  SETGROUP MICECARE // listen to other mice
 }
RETURN

>>SAVE_BEHAVIOR
 TIMERcolplayer OFF 
// to avoid TIMERcolplayer to restore the behavior 1 sec later
 IF (§main_behavior_stacked == 0) 
 {
  IF (§frozen == 1)
  { 
// frozen anim -> wake up !
    SET §frozen 0
    PLAYANIM NONE
    PLAYANIM -2 NONE
    PHYSICAL ON
    COLLISION ON
    BEHAVIOR FRIENDLY
    SETTARGET PLAYER
  }
  SET §main_behavior_stacked 1
  HEROSAY -d "STACK"
  BEHAVIOR STACK
 }
 ELSE
 { // behavior already saved : clear mice target if one
  GOSUB CLEAR_MICE_TARGET
 }
RETURN

>>RESTORE_BEHAVIOR
 IF (§main_behavior_stacked == 1) 
 {
  GOSUB CLEAR_MICE_TARGET
  HEROSAY -d "UNSTACK"
  BEHAVIOR UNSTACK
  SET §main_behavior_stacked 0
  RETURN
 }
IF (£init_marker != "NONE")
  { 
   BEHAVIOR MOVE_TO
   SETTARGET -a ~£init_marker~
   SETMOVEMODE WALK
   RETURN
  }
HEROSAY -d "go_home"
BEHAVIOR GO_HOME
SETTARGET PLAYER
RETURN

// ---------------------------------------------------------------------------------
// BEHAVIOR INCLUDE END ------------------------------------------------------------
// ---------------------------------------------------------------------------------

//#
//#LocalChat
// ---------------------------------------------------------------------------------
// LocalChat INCLUDE START ---------------------------------------------------------
// ---------------------------------------------------------------------------------
>>START_CHAT
 // save misc reflection mode
 SET §saved_reflection §reflection_mode
 // no more stupid reflections !
 SET §reflection_mode 0
 // fo not change behavior if frozen
 IF ( §frozen == 1 ) RETURN
 // save behavior (if not saved)
 GOSUB SAVE_BEHAVIOR
 // look at player
 BEHAVIOR FRIENDLY
 SETTARGET PLAYER
RETURN

>>END_CHAT
 SET_EVENT COLLIDE_NPC ON
 SET §collided_player 0
 // restor behavior only if not in fighting mode
 IF ( §fighting_mode == 0 )
 {
  // restore misc reflection mode
  SET §reflection_mode §saved_reflection
  // if frozen : don't restore behavior
  IF ( §frozen == 1 ) RETURN
  // restore behavior
  GOSUB RESTORE_BEHAVIOR
 }
RETURN
// ---------------------------------------------------------------------------------
// LocalChat INCLUDE END -----------------------------------------------------------
// ---------------------------------------------------------------------------------

//#